;;;Place breakline symbol as a polyline.
;;;
;;;
;;;              
;;;
;;;>	Author:	Henry C. Francis
;;;>		425 N. Ashe St.
;;;>		Southern Pines, NC 28387
;;;>		http://paracadd.com
;;;>		All rights reserved.
;;;
;;;>		COPYRIGHT: 6-16-94
;;;>		   EDITED: 10-06-2005
;;;
(DEFUN C:BRKL (/       bkp1b   bkp1m   bkp1r   bkp1l   bkp1a   bkp2b
	       bkp2m   bkp2r   bkp2l   bkp2a   bkp3b   bkp3m   bkp3r
	       bkp3l   bkp3a
	      )
  (IF mklayr
    nil
    (LOAD "mklayr")
  ) ;_ end of if
  (c:svlayr)
  (SETQ	colr "1"
	modf "SYMB"
  ) ;_ end of setq
  (c:mklayr)
  (IF dimscl
    nil
    (LOAD "dimscl")
  ) ;_ end of if
  (dimscl)
  (SETQ old_osmode (GETVAR "osmode"))
  (SETVAR "osmode" 0)
  (IF upoint NIL (LOAD "upoint" "\nFile UPOINT.LSP not loaded! "))
  (WHILE
    (AND
      (SETQ pt1 (upoint 0 "" "\nBeginning point of breakline " pt2 nil))
      (SETQ pt2 (upoint 0 "" "\nEnding point of breakline " nil pt1))
    )					;and
     (SETQ lang	(ANGLE pt1 pt2)
	   gnal	(ANGLE pt2 pt1)
	   lan1	(+ lang (/ PI 2.0) 0.15)
	   lan2	(- lang (- (/ PI 2.0) 0.15))
	   bdis	(DISTANCE pt1 pt2)
	   ofin	(* dimsc 0.045)
	   offs	(* dimsc 0.135)
	   bnum	(FIX (/ bdis (* 50 ofin)))
     )					;setq
     (IF (> bnum 3)
       (SETQ bnum 3)
     )					;
     (SETQ count (1+ bnum))
     (IF (= count 1)
       (SETQ len1 (/ bdis 2.0))
       (SETQ len1 (/ bdis count))
     )					;if
     (SETQ bkp1m (POLAR pt1 lang len1)
	   bkp1b (POLAR bkp1m gnal ofin)
	   bkp1r (POLAR bkp1m lan1 offs)
	   bkp1l (POLAR bkp1m lan2 offs)
	   bkp1a (POLAR bkp1m lang ofin)
	   bkp2m (POLAR bkp1m lang len1)
	   bkp2b (POLAR bkp2m gnal ofin)
	   bkp2r (POLAR bkp2m lan1 offs)
	   bkp2l (POLAR bkp2m lan2 offs)
	   bkp2a (POLAR bkp2m lang ofin)
	   bkp3m (POLAR bkp2m lang len1)
	   bkp3b (POLAR bkp3m gnal ofin)
	   bkp3r (POLAR bkp3m lan1 offs)
	   bkp3l (POLAR bkp3m lan2 offs)
	   bkp3a (POLAR bkp3m lang ofin)
     )					;setq
     (IF (> bdis (DISTANCE bkp1b bkp1a))
       (IF (OR (= bnum 1) (= bnum 0))
	 (PROGN
	   (COMMAND)
	   (COMMAND ".pline" pt1 bkp1b bkp1r bkp1l bkp1a pt2 "")
	 )				;progn
	 (IF (= bnum 2)
	   (PROGN
	     (COMMAND)
	     (COMMAND ".pline"	      pt1     bkp1b   bkp1r   bkp1l
		      bkp1a   bkp2b   bkp2r   bkp2l   bkp2a   pt2
		      ""
		     ) ;_ end of command
	   )				;progn
	   (PROGN
	     (COMMAND)
	     (COMMAND ".pline"	      pt1     bkp1b   bkp1r   bkp1l
		      bkp1a   bkp2b   bkp2r   bkp2l   bkp2a   bkp3b
		      bkp3r   bkp3l   bkp3a   pt2     ""
		     ) ;_ end of command
	   )				;progn
	 )				;if
       )				;if
       (PROMPT "\nDistance too short for breakline ")
     )					;if
  )					;while
  (c:rslayr)
  (COMMAND)
  (SETVAR "osmode" old_osmode)
  (PRINC)
)					;defun brkl
;|«Visual LISP© Format Options»
(72 2 40 2 T "end of " 60 9 2 0 0 T T nil T)
;*** DO NOT add text below the comment! ***|;