;;;Automatic placement of bore & jack casing pipe in plan.
;;;
;;;>	Author:	Henry C. Francis
;;;>		425 N. Ashe St.
;;;>		Southern Pines, NC 28387
;;;>		http://paracadd.com
;;;>		All rights reserved.
;;;
;;;>		COPYRIGHT: 1-30-96
;;;>		   EDITED: 04-08-1997
;;;
(defun c:bjpln (/); segm slin opt1 sent pt1 pt2 hpln lang plpc plp1 plp2 plp3 plp4
  (setq osmod (getvar"osmode")
        segm "T"
        colr "2"
        llt "-"
        prod "SSWR"
        modf "NEWW"
  );setq
  (setvar "osmode" 0)
  (setq slin (car(nentsel "\nSelect Line: ")))
  (c:svlayr)
  (c:mklayr)
  (setq sent (entget slin))
  (setq opt1 (upoint 1 "" "Beginning Station" nil nil))
  (setq opt1 (list(car opt1)(cadr opt1))
        pt1 (cdr(assoc 10 sent))
        pt1 (list(car pt1)(cadr pt1))
  );setq
  (if(eq(cdr(assoc 0 sent))"VERTEX")
    (setq pt2 (cdr(assoc 10(entget(entnext slin))))
          pt2 (list(car pt2)(cadr pt2))
    );setq
    (setq pt2 (cdr(assoc 11 sent))
          pt2 (list(car pt2)(cadr pt2))
    );setq 
  );if
  (setq caln (uint 1 "" "Casing Length (feet)" (if caln caln nil)))
  (setq hpln (/ caln 2.00)
        lang (angle pt1 pt2)
  );setq
  (if (<(distance pt1 opt1)(distance pt2 opt1))
    (setq opt1 (inters opt1 (polar opt1(+ lang(/ pi 2))100) pt1 pt2)
          plpc (polar opt1 lang hpln)
    );setq
    (setq opt1 (inters opt1 (polar opt1(+ lang(/ pi 2))100) pt1 pt2)
          plpc (polar opt1 (+ lang pi) hpln)
    );setq
  );if
  (setq plp1 (polar(polar plpc lang hpln)(+ lang(/ pi 2))4)
        plp2 (polar plp1 (+ lang pi) caln)
        plp3 (polar plp2 (+ lang(* pi 1.5))8)
        plp4 (polar plp3 lang caln)
  );setq
  (command ".pline" plp1 plp2 plp3 plp4 "c")
  (c:rslayr)
  (setvar"osmode"osmod)
  (princ)
);defun