;;;Modify the text height of a selection
;;;set of text entities.  The only input required is the desired
;;;text height factor and selection of the text to modify.  There
;;;is no need to worry about not selecting non-text entities
;;;because they will be automatically filtered out of the
;;;selection set.
;;;Uses TXTSIZE.LSP and USTR.LSP
;;;
;;;>	Author:	Henry C. Francis
;;;>		425 N. Ashe St.
;;;>		Southern Pines, NC 28387
;;;>		http://paracadd.com
;;;>		All rights reserved.
;;;
;;;>		COPYRIGHT: 1994-2001
;;;>		   EDITED: 03-02-2001
;;;
(DEFUN C:thgt (/)			;tht tset tsln cntr tent edtw)
  (if txtsize
    nil
    (load "txtsize")
  ) ;_ end of if
  (txtsize nil)
  (prompt "\nSelect Text: ")
  (setq	tset (ssget '((-4 . "<or")
		      (0 . "TEXT")
		      (0 . "ATTDEF")
		      (0 . "INSERT")
		      (-4 . "or>")
		     )
	     ) ;_ end of ssget
  ) ;_ end of setq
  (if tset
    (progn
      (setq tsln (sslength tset))
      (setq cntr 0)
    ) ;_ end of progn
  ) ;_ end of if
  (while
    (if	(and (< cntr tsln) tset)
      (setq tent (entget (ssname tset cntr)))
    )					;if
     (progn
       (setq edtw (entget (cdar tent)))
       (if (eq (cdr (assoc 0 edtw)) "INSERT")
	 (progn
	   (setq subent edtw)
	   (while (not (eq "SEQEND" (cdr (assoc 0 subent))))
	     (if (eq "ATTRIB" (cdr (assoc 0 subent)))
	       (progn
		 (setq subent
			(subst (cons 40 txtht)
			       (assoc 40 subent)
			       subent
			) ;_ end of subst
		 ) ;_ end of setq
		 (entmod subent)
	       ) ;_ end of progn
	     )				;if
	     (setq subent (entget (entnext (cdr (assoc -1 subent)))))
	   )				;while
	   (entmod edtw)
	 )				;progn
	 (progn
	   (setq edtw
		  (subst (cons 40 txtht)
			 (assoc 40 edtw)
			 edtw
		  ) ;_ end of subst
	   ) ;_ end of setq
	   (entmod edtw)
	 ) ;_ end of progn
       )				;if
       (setq cntr (1+ cntr))
     ) ;_ end of progn
  ) ;_ end of while
  (princ)
)					;DEFUN

;|«Visual LISP© Format Options» (72 2 40 2 T "end of " 60 9 0 0 0 T T nil T)
 ***Don't add text below the comment!***|;